Open-AudIT

Hi everyone,
I did the update to OAv2 (beta9.2) from v1 on a Ubuntu 12.10 with xampp. I like new feature & design but I have a problem with Windows audit:
When I audit a Win 7 x64 (maybe x86 ?) Enterprise, the OS_Family information return as an empty value(see the attachment), how can I resolve this situation ?
I did also a "quick" french translation in attachment and I have made an additional autodesk software licence audit in an other attachment.
thanks for your help.
Franck

Try with the latest script from OAb9.2 as the attached isn't the latest version. But that's probably not the problem. Put the code below in a test.vbs file and then run on a problem machine and report back with the output.

[code]set objWMIService = GetObject("winmgmts:\\.\root\cimv2")
set colItems = objWMIService.ExecQuery("Select * from Win32_OperatingSystem",,32)
for each objItem in colItems
wscript.echo "Caption: " & objItem.Caption
next[/code]

Hi Jpa,
I have the same result with the latest script audit and "Caption: Microsoft Windows 7 Entreprise" for the test script.
Thanks for your help

What do you get when you run the following at a command prompt?

[code]set objWMIService = GetObject("winmgmts:\\.\root\cimv2")
set colItems = objWMIService.ExecQuery("Select * from Win32_OperatingSystem",,32)
for each objItem in colItems
wscript.echo "Caption: " & objItem.Caption
wscript.echo "Family Binary: " & os_family(objItem.Caption, vbBinaryCompare)
wscript.echo "Family Text: " & os_family(objItem.Caption, vbTextCompare)
next

function os_family(os,comp)
if InStr(1, os, " 95", comp) then os_family="Windows 95"
if InStr(1, os, " 98", comp) then os_family="Windows 98"
if InStr(1, os, " NT", comp) then os_family="Windows NT"
if InStr(1, os, "2000", comp) then os_family="Windows 2000"
if InStr(1, os, " XP", comp) then os_family="Windows XP"
if InStr(1, os, "2003", comp) then os_family="Windows 2003"
if InStr(1, os, "Vista", comp) then os_family="Windows Vista"
if InStr(1, os, "2008", comp) then os_family="Windows 2008"
if InStr(1, os, "Windows 7", comp) then os_family="Windows 7"
if InStr(1, os, "Windows 8", comp) then os_family="Windows 8"
end function[/code]

Caption: Microsoft Windows 7 Entreprise
Family Binary:
Family Text:

Interesting. There must be something in the actual output that we're not seeing. How about the following?

[code]set objWMIService = GetObject("winmgmts:\\.\root\cimv2")
set colItems = objWMIService.ExecQuery("Select * from Win32_OperatingSystem",,32)
for each objItem in colItems
wscript.echo "Caption: " & objItem.Caption
wscript.echo "Family Binary: " & os_family(objItem.Caption, vbBinaryCompare)
wscript.echo "Family Text: " & os_family(objItem.Caption, vbTextCompare)
next

function os_family(os,comp)
if InStr(1, os, " 95", comp) then os_family="Windows 95"
if InStr(1, os, " 98", comp) then os_family="Windows 98"
if InStr(1, os, " NT", comp) then os_family="Windows NT"
if InStr(1, os, "2000", comp) then os_family="Windows 2000"
if InStr(1, os, " XP", comp) then os_family="Windows XP"
if InStr(1, os, "2003", comp) then os_family="Windows 2003"
if InStr(1, os, "Vista", comp) then os_family="Windows Vista"
if InStr(1, os, "2008", comp) then os_family="Windows 2008"
if InStr(1, os, "7", comp) then os_family="Windows 7"
if InStr(1, os, "8", comp) then os_family="Windows 8"
end function[/code]

Caption: Microsoft Windows 7 Entreprise
Family Binary: Windows 7
Family Text: Windows 7

Better, no ?

Or the output of this last attempt before I give up as incompetent. We need to figure out what, exactly, your Caption value contains.

[code]set objWMIService = GetObject("winmgmts:\\.\root\cimv2")
set colItems = objWMIService.ExecQuery("Select * from Win32_OperatingSystem",,32)
for each objItem in colItems
wscript.echo "Caption: " & StringToAscii(objItem.Caption)
wscript.echo "Family: " & os_family(objItem.Caption, vbBinaryCompare)
next

function os_family(os,comp)
if InStr(1, os, " 95", comp) then os_family="Windows 95"
if InStr(1, os, " 98", comp) then os_family="Windows 98"
if InStr(1, os, " NT", comp) then os_family="Windows NT"
if InStr(1, os, "2000", comp) then os_family="Windows 2000"
if InStr(1, os, " XP", comp) then os_family="Windows XP"
if InStr(1, os, "2003", comp) then os_family="Windows 2003"
if InStr(1, os, "Vista", comp) then os_family="Windows Vista"
if InStr(1, os, "2008", comp) then os_family="Windows 2008"
if InStr(1, os, "7", comp) then os_family="Windows 7"
if InStr(1, os, "8", comp) then os_family="Windows 8"
end function

Function StringToAscii(str)
Dim result, x
StringToAscii = ""
If Len(str)=0 Then Exit Function
If Len(str)=1 Then
result = Asc(Mid(str, 1, 1))
StringToAscii = Left("000", 3-Len(CStr(result))) & CStr(result)
Exit Function
End If
result = ""
For x=1 To Len(str)
result = result & StringToAscii(Mid(str, x, 1))
Next
StringToAscii = result
End Function[/code]

Goodluck

Caption: 077105099114111115111102116032087105110100111119115160055032069110116114101112114105115101032
Family: Windows 7

OK. Maybe I'm not completely incompetent. Replace your os_family function in your audit script with the code below and hopefully it will work. No guarantees.

If Mark sees this he can add it to the official script. Although he'll probably do it differently. It's probably better to do the replace to the retrieved caption value rather than just the os family.

[code]function os_family(os)
os = replace(os, chr(160)," ")
if InStr(os, " 95") then os_family="Windows 95"
if InStr(os, " 98") then os_family="Windows 98"
if InStr(os, " NT") then os_family="Windows NT"
if InStr(os, "2000") then os_family="Windows 2000"
if InStr(os, " XP") then os_family="Windows XP"
if InStr(os, "2003") then os_family="Windows 2003"
if InStr(os, "Vista") then os_family="Windows Vista"
if InStr(os, "2008") then os_family="Windows 2008"
if InStr(os, "Windows 7") then os_family="Windows 7"
if InStr(os, "Windows 8") then os_family="Windows 8"
if InStr(os, "2012") then os_family="Windows 2012"
end function[/code]

Hi Jpa,
This is working!
Many thanks for your help

Included. Look for it in the next release.

_________________
Support and Development hours available from [url=https://opmantek.com]Opmantek[/url].
Please consider a purchase to help make Open-AudIT better for everyone.